[SYCL][Cmake] Redesign opencl dependencies

* Moved from ExternalProject to FetchContent:
  * External dependencies are downloaded at configure stage, not build
  * All dependencies targets become available earlier and become reusable
  * All dependencies are consolidated under _deps directory
  * Simplified cmake files for better maintenance
* Outline opencl deps into separate opencl/CMakeLists.txt
* Update other targets to new deps accordingly
* Added comments inlined for not very clear logic in our cmake build system

Signed-off-by: Pavel V Chupin <pavel.v.chupin@intel.com>

Author: Pavel V Chupin

opencl/CMakeLists.txt

@@ -0,0 +1,45 @@
+cmake_minimum_required(VERSION 3.14)
+
+include(FetchContent)
+
+# OpenCL Headers
+if(NOT OpenCL_INCLUDE_DIRS)
+  message(STATUS "Will fetch OpenCL headers from github.com")
+
+  FetchContent_Declare(ocl-headers
+    GIT_REPOSITORY    https://github.com/KhronosGroup/OpenCL-Headers.git
+    GIT_TAG           23710f1b99186065c1768fc3098ba681adc0f253
+  )
+
+  FetchContent_MakeAvailable(ocl-headers)
+  FetchContent_GetProperties(ocl-headers)
+  set(OpenCL_INCLUDE_DIRS ${ocl-headers_SOURCE_DIR})
+else()
+  message(STATUS "OpenCL headers are added manually ${OpenCL_INCLUDE_DIRS}")
+endif()
+
+target_compile_definitions(Headers INTERFACE -DCL_TARGET_OPENCL_VERSION=220)
+add_library(OpenCL-Headers ALIAS Headers)
+
+# OpenCL Library (ICD Loader)
+
+# Set OPENCL_ICD_LOADER_HEADERS_DIR, as prerequisite for ICD build
+set(OPENCL_ICD_LOADER_HEADERS_DIR ${OpenCL_INCLUDE_DIRS} CACHE PATH "Path to OpenCL Headers")
+
+if(NOT OpenCL_LIBRARY)
+  message(STATUS "Will fetch OpenCL ICD Loader from github.com")
+
+  FetchContent_Declare(ocl-icd
+    GIT_REPOSITORY    https://github.com/KhronosGroup/OpenCL-ICD-Loader.git
+    GIT_TAG           5f8249691ec8c25775789498951f8e9eb62c201d
+  )
+
+  FetchContent_MakeAvailable(ocl-icd)
+  FetchContent_GetProperties(ocl-icd)
+  set(OpenCL_LIBRARY ${ocl-icd_SOURCE_DIR})
+else()
+  message(STATUS "OpenCL ICD Loader is added manually ${OpenCL_LIBRARY}")
+endif()
+
+add_library(OpenCL-ICD ALIAS OpenCL)
+

sycl/CMakeLists.txt

@@ -71,130 +71,23 @@ set(SYCL_INCLUDE_DIR "include")
 set(SYCL_INCLUDE_BUILD_DIR ${LLVM_BINARY_DIR}/${SYCL_INCLUDE_DIR})
 set(SYCL_INCLUDE_DEPLOY_DIR ${CMAKE_INSTALL_PREFIX}/${SYCL_INCLUDE_DIR})
 
-# Find OpenCL headers and libraries installed in the system and use them to
-# build SYCL runtime.
-# WARNING: use with caution, building SYCL runtime with OpenCL implementation
-# instead of Khronos ICD loader might cause build and/or portability issues.
-option(OpenCL_BUILD_WITH_SYSTEM_SDK "Build SYCL with OpenCL coming from the build system" OFF)
-
-if( (OpenCL_INCLUDE_DIR AND OpenCL_LIBRARY) OR OpenCL_BUILD_WITH_SYSTEM_SDK)
-  find_package(OpenCL)
-endif()
-
-include(ExternalProject)
-
-# By default, whenever cmake is re-run, the external project's sources will be
-# updated, which might be annoying - let's have a possibility to disable that as
-# not every external project which is used here is being updated often
-# Single toggle to control all external projects
-option(SYCL_EXTERNAL_PROJECTS_SKIP_AUTO_UPDATE
-  "Perform automatic update step for external projects (OpenCL Headers, OpenCL ICD, etc.)" OFF)
-# More precise controls for each particular external project are documented
-# near each ExternalProject_Add
-
-if( NOT OpenCL_INCLUDE_DIRS )
-  message(STATUS "OpenCL_INCLUDE_DIRS is missing. Will try to download OpenCL headers from github.com")
-  set(OpenCL_INCLUDE_DIRS "${CMAKE_CURRENT_BINARY_DIR}/OpenCL/inc")
-  if (NOT DEFINED SYCL_EP_OCL_HEADERS_SKIP_AUTO_UPDATE)
-    set(SYCL_EP_OCL_HEADERS_SKIP_AUTO_UPDATE ${SYCL_EXTERNAL_PROJECTS_SKIP_AUTO_UPDATE})
-  endif()
-  ExternalProject_Add(ocl-headers
-    GIT_REPOSITORY    https://github.com/KhronosGroup/OpenCL-Headers.git
-    GIT_TAG           23710f1b99186065c1768fc3098ba681adc0f253
-    UPDATE_DISCONNECTED ${SYCL_EP_OCL_HEADERS_SKIP_AUTO_UPDATE}
-    SOURCE_DIR        ${OpenCL_INCLUDE_DIRS}
-    CONFIGURE_COMMAND ""
-    BUILD_COMMAND     ${CMAKE_COMMAND} -E copy_directory ${OpenCL_INCLUDE_DIRS}/CL ${SYCL_INCLUDE_BUILD_DIR}/sycl/CL
-    INSTALL_COMMAND   ""
-    STEP_TARGETS      build
-    COMMENT           "Downloading OpenCL headers."
-    LOG_DOWNLOAD 1
-    LOG_UPDATE 1
-    LOG_BUILD 1
-  )
-  add_definitions(-DCL_TARGET_OPENCL_VERSION=220)
-else()
-  add_custom_target( ocl-headers ALL
-    DEPENDS ${OpenCL_INCLUDE_DIRS}
-    COMMAND ${CMAKE_COMMAND} -E copy_directory ${OpenCL_INCLUDE_DIRS}/CL ${SYCL_INCLUDE_BUILD_DIR}/sycl/CL
-    COMMENT "Copying OpenCL headers ..."
-  )
-endif()
-
-if( NOT OpenCL_LIBRARIES )
-  message(STATUS "OpenCL_LIBRARIES is missing. Will try to download OpenCL ICD Loader from github.com")
-  if(MSVC)
-    set(OpenCL_LIBRARIES
-        "${LLVM_LIBRARY_OUTPUT_INTDIR}/${CMAKE_STATIC_LIBRARY_PREFIX}OpenCL${CMAKE_STATIC_LIBRARY_SUFFIX}")
-    list(APPEND AUX_CMAKE_FLAGS -DOPENCL_ICD_LOADER_REQUIRE_WDK=OFF)
-  else()
-    set(OpenCL_LIBRARIES
-        "${LLVM_LIBRARY_OUTPUT_INTDIR}/${CMAKE_SHARED_LIBRARY_PREFIX}OpenCL${CMAKE_SHARED_LIBRARY_SUFFIX}")
-  endif()
-  if (CMAKE_C_COMPILER)
-    list(APPEND AUX_CMAKE_FLAGS -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER})
-  endif()
-  if (CMAKE_CXX_COMPILER)
-    list(APPEND AUX_CMAKE_FLAGS -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER})
-  endif()
-  file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/icd_build)
-  set(OpenCL_ICD_LOADER_SOURCE_DIR "${CMAKE_CURRENT_BINARY_DIR}/OpenCL/icd")
-  if (NOT DEFINED SYCL_EP_OCL_ICD_SKIP_AUTO_UPDATE)
-    set(SYCL_EP_OCL_ICD_SKIP_AUTO_UPDATE ${SYCL_EXTERNAL_PROJECTS_SKIP_AUTO_UPDATE})
-  endif()
-  ExternalProject_Add(ocl-icd
-    GIT_REPOSITORY    https://github.com/KhronosGroup/OpenCL-ICD-Loader.git
-    GIT_TAG           5f8249691ec8c25775789498951f8e9eb62c201d
-    UPDATE_DISCONNECTED ${SYCL_EP_OCL_ICD_SKIP_AUTO_UPDATE}
-    SOURCE_DIR        ${OpenCL_ICD_LOADER_SOURCE_DIR}
-    BINARY_DIR        "${CMAKE_CURRENT_BINARY_DIR}/icd_build"
-    INSTALL_DIR       "${CMAKE_CURRENT_BINARY_DIR}/icd_install"
-    CMAKE_ARGS -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
-               -DCMAKE_MAKE_PROGRAM=${CMAKE_MAKE_PROGRAM}
-               -DOPENCL_ICD_LOADER_HEADERS_DIR=${OpenCL_INCLUDE_DIRS}
-               -DCMAKE_INSTALL_PREFIX=<INSTALL_DIR>
-               -DCMAKE_INSTALL_LIBDIR:PATH=lib${LLVM_LIBDIR_SUFFIX}
-               ${AUX_CMAKE_FLAGS}
-    STEP_TARGETS      configure,build,install
-    DEPENDS           ocl-headers
-    BUILD_BYPRODUCTS ${OpenCL_LIBRARIES}
-    LOG_DOWNLOAD 1
-    LOG_UPDATE 1
-    LOG_CONFIGURE 1
-    LOG_BUILD 1
-    LOG_INSTALL 1
-  )
-  ExternalProject_Add_Step(ocl-icd llvminstall
-    COMMAND ${CMAKE_COMMAND} -E copy_directory <INSTALL_DIR>/ ${LLVM_BINARY_DIR}
-    COMMENT "Installing ocl-icd into the LLVM binary directory"
-    DEPENDEES install
-  )
-  # Optionally install the ICD library along with LLVM.
-  option(OpenCL_INSTALL_KHRONOS_ICD_LOADER
-    "Install the Khronos ICD Loader built as part of LLVM" OFF)
-  if (OpenCL_INSTALL_KHRONOS_ICD_LOADER)
-    install(DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/icd_install/"
-      DESTINATION "."
-      COMPONENT opencl-icd
-    )
-  endif()
-else()
-  file(GLOB ICD_LOADER_SRC "${OpenCL_LIBRARIES}*")
-  file(COPY ${ICD_LOADER_SRC} DESTINATION ${LLVM_LIBRARY_OUTPUT_INTDIR})
-  add_custom_target(ocl-icd DEPENDS ${OpenCL_LIBRARIES} COMMENT "Copying OpenCL ICD Loader ...")
-endif()
-
-set(OPENCL_INCLUDE "${OpenCL_INCLUDE_DIRS}")
-
-add_library (OpenCL-Headers INTERFACE)
-add_library (OpenCL::Headers ALIAS OpenCL-Headers)
-target_include_directories(OpenCL-Headers
-  INTERFACE ${OPENCL_INCLUDE}
-)
-install(DIRECTORY ${OPENCL_INCLUDE}/CL
-  DESTINATION ${SYCL_INCLUDE_DEPLOY_DIR}/sycl
-  COMPONENT opencl-headers
-)
+# LLVM build sets this OFF by default, but we need OpenCL to be built as shared
+# library.
+set(BUILD_SHARED_LIBS ON)
+# second argument is not used, it's required since first arg is not a real
+# subdirectory
+add_subdirectory(../opencl ${CMAKE_CURRENT_BINARY_DIR}/opencl_deps)
+
+# Copy OpenCL Headers into sycl headers build directory
+# Compiler does automatic lookup bin/../include based on clang binary location,
+# e.g. when run LIT tests
+file(COPY ${OPENCL_ICD_LOADER_HEADERS_DIR}/CL
+     DESTINATION ${SYCL_INCLUDE_BUILD_DIR}/sycl)
+
+# Include OpenCL Headers into final bundle.
+install(DIRECTORY ${OPENCL_ICD_LOADER_HEADERS_DIR}/CL
+        DESTINATION ${SYCL_INCLUDE_DEPLOY_DIR}/sycl
+        COMPONENT OpenCL-Headers)
 
 option(SYCL_BUILD_PI_CUDA
   "Enables the CUDA backend for the Plugin Interface" OFF)
@@ -207,13 +100,13 @@ string(TIMESTAMP __SYCL_COMPILER_VERSION "%Y%m%d")
 set(version_header "${sycl_inc_dir}/CL/sycl/version.hpp")
 configure_file("${version_header}.in" "${version_header}")
 
-# Copy SYCL headers
+# Copy SYCL headers from sources to build directory
 add_custom_target(sycl-headers ALL
 COMMAND ${CMAKE_COMMAND} -E copy_directory ${sycl_inc_dir}/sycl ${SYCL_INCLUDE_BUILD_DIR}/sycl
 COMMAND ${CMAKE_COMMAND} -E copy_directory ${sycl_inc_dir}/CL ${SYCL_INCLUDE_BUILD_DIR}/sycl/CL
 COMMENT "Copying SYCL headers ...")
 
-# Configure SYCL headers
+# Copy SYCL headers from sources to install directory
 install(DIRECTORY "${sycl_inc_dir}/sycl" DESTINATION ${SYCL_INCLUDE_DEPLOY_DIR} COMPONENT sycl-headers)
 install(DIRECTORY "${sycl_inc_dir}/CL" DESTINATION ${SYCL_INCLUDE_DEPLOY_DIR}/sycl COMPONENT sycl-headers)
 
@@ -353,7 +246,7 @@ set( SYCL_TOOLCHAIN_DEPLOY_COMPONENTS
      sycl-post-link
      sycl-ls
      clang-resource-headers
-     opencl-headers
+     OpenCL-Headers
      sycl-headers
      sycl-headers-extras
      sycl
@@ -363,8 +256,8 @@ set( SYCL_TOOLCHAIN_DEPLOY_COMPONENTS
      ${XPTIFW_LIBS}
 )
 
-if(OpenCL_INSTALL_KHRONOS_ICD_LOADER AND TARGET ocl-icd)
-  list(APPEND SYCL_TOOLCHAIN_DEPLOY_COMPONENTS opencl-icd)
+if(OpenCL_INSTALL_KHRONOS_ICD_LOADER AND TARGET OpenCL-ICD)
+  list(APPEND SYCL_TOOLCHAIN_DEPLOY_COMPONENTS OpenCL-ICD)
 endif()
 
 if(SYCL_BUILD_PI_CUDA)

sycl/plugins/cuda/CMakeLists.txt

@@ -10,7 +10,7 @@ find_package(CUDA 10.1 REQUIRED)
 add_library(cudadrv SHARED IMPORTED GLOBAL)
 
 set_target_properties(
-  cudadrv PROPERTIES 
+  cudadrv PROPERTIES
     IMPORTED_LOCATION             ${CUDA_CUDA_LIBRARY}
     INTERFACE_INCLUDE_DIRECTORIES ${CUDA_INCLUDE_DIRS}
 )
@@ -22,22 +22,21 @@ add_library(pi_cuda SHARED
   "pi_cuda.cpp"
 )
 
-add_dependencies(pi_cuda
-  ocl-headers
-)
-
 add_dependencies(sycl-toolchain pi_cuda)
 
 set_target_properties(pi_cuda PROPERTIES LINKER_LANGUAGE CXX)
 
 target_include_directories(pi_cuda
   PRIVATE
     ${sycl_inc_dir}
+    ${OPENCL_ICD_LOADER_HEADERS_DIR}
   PUBLIC
     ${CUDA_INCLUDE_DIRS}
 )
 
-target_link_libraries(pi_cuda PUBLIC OpenCL-Headers cudadrv)
+target_link_libraries(pi_cuda
+  PRIVATE OpenCL-Headers
+  PUBLIC cudadrv)
 
 add_common_options(pi_cuda)
 

sycl/plugins/level_zero/CMakeLists.txt

@@ -21,6 +21,11 @@ if (NOT DEFINED LEVEL_ZERO_LIBRARY OR NOT DEFINED LEVEL_ZERO_INCLUDE_DIR)
   if (NOT DEFINED SYCL_EP_LEVEL_ZERO_LOADER_SKIP_AUTO_UPDATE)
     set(SYCL_EP_LEVEL_ZERO_LOADER_SKIP_AUTO_UPDATE ${SYCL_EXTERNAL_PROJECTS_SKIP_AUTO_UPDATE})
   endif()
+
+  #TODO: Replace ExternalProject with FetchContent for better maintainance and
+  #      cmake files simplification
+  include(ExternalProject)
+
   ExternalProject_Add(level-zero-loader
     GIT_REPOSITORY    https://github.com/oneapi-src/level-zero.git
     GIT_TAG           v1.0.16
@@ -40,7 +45,7 @@ if (NOT DEFINED LEVEL_ZERO_LIBRARY OR NOT DEFINED LEVEL_ZERO_INCLUDE_DIR)
                LOG_BUILD 1
                LOG_INSTALL 1
     STEP_TARGETS      configure,build,install
-    DEPENDS           ocl-headers
+    DEPENDS           OpenCL-Headers
     BUILD_BYPRODUCTS ${LEVEL_ZERO_LOADER}
   )
   ExternalProject_Add_Step(level-zero-loader llvminstall
@@ -91,8 +96,8 @@ target_include_directories(LevelZeroLoader-Headers
   INTERFACE "${LEVEL_ZERO_INCLUDE_DIR}"
 )
 
+
 include_directories("${sycl_inc_dir}")
-include_directories(${OPENCL_INCLUDE})
 
 add_library(pi_level_zero SHARED
   "${sycl_inc_dir}/CL/sycl/detail/pi.h"
@@ -125,9 +130,13 @@ endif()
 if (TARGET level-zero-loader)
   add_dependencies(pi_level_zero level-zero-loader)
 endif()
-  add_dependencies(sycl-toolchain pi_level_zero)
 
-  target_link_libraries(pi_level_zero PRIVATE "${LEVEL_ZERO_LOADER}")
+add_dependencies(sycl-toolchain pi_level_zero)
+target_link_libraries(pi_level_zero
+  PRIVATE "${LEVEL_ZERO_LOADER}"
+  PRIVATE OpenCL-Headers
+)
+
 if (UNIX)
   target_link_libraries(pi_level_zero PRIVATE pthread)
 endif()

sycl/plugins/opencl/CMakeLists.txt

@@ -7,19 +7,14 @@
 # Plugin for OpenCL
 # Create Shared library for libpi_opencl.so.
 #TODO: remove dependency on pi.hpp in sycl project.
-#TODO: Currently, the pi.hpp header is common between sycl and plugin library sources. 
+#TODO: Currently, the pi.h header is common between sycl and plugin library sources.
 #This can be changed by copying the pi.hpp file in the plugins project.
 
 add_library(pi_opencl SHARED
   "${sycl_inc_dir}/CL/sycl/detail/pi.h"
   "pi_opencl.cpp"
   )
 
-add_dependencies(pi_opencl
-  ocl-icd
-  ocl-headers
-)
-
 add_dependencies(sycl-toolchain pi_opencl)
 
 set_target_properties(pi_opencl PROPERTIES LINKER_LANGUAGE CXX)
@@ -28,9 +23,9 @@ set_target_properties(pi_opencl PROPERTIES LINKER_LANGUAGE CXX)
 target_include_directories(pi_opencl PRIVATE "${sycl_inc_dir}")
 
 #link pi_opencl with OpenCL headers and ICD Loader.
-target_link_libraries( pi_opencl
-  PRIVATE OpenCL::Headers
-  PRIVATE ${OpenCL_LIBRARIES}
+target_link_libraries(pi_opencl
+  PRIVATE OpenCL-Headers
+  PRIVATE OpenCL-ICD
 )
 if (MSVC)
   # by defining __SYCL_BUILD_SYCL_DLL, we can use __declspec(dllexport)
@@ -46,7 +41,7 @@ else()
   set(linker_script "${CMAKE_CURRENT_SOURCE_DIR}/../ld-version-script.txt")
 
   # Filter symbols based on the scope defined in the script file,
-  # and export pi* function symbols in the library. 
+  # and export pi* function symbols in the library.
   target_link_libraries( pi_opencl
     PRIVATE "-Wl,--version-script=${linker_script}"
   )

sycl/source/CMakeLists.txt

@@ -32,10 +32,7 @@ function(add_sycl_rt_library LIB_NAME)
     target_compile_options(${LIB_OBJ_NAME} PRIVATE ${ARG_COMPILE_OPTIONS})
   endif()
 
-  #To-Do: Remove dependency on icd loader and opencl headers.
   add_dependencies(${LIB_OBJ_NAME}
-    ocl-icd
-    ocl-headers
     sycl-headers
   )
 
@@ -68,14 +65,17 @@ function(add_sycl_rt_library LIB_NAME)
     PRIVATE
       ${CMAKE_CURRENT_SOURCE_DIR}
       "${sycl_inc_dir}"
-      ${OpenCL_INCLUDE_DIRS}
+  )
+  #TODO: Remove dependency on icd loader and opencl headers.
+  target_link_libraries(${LIB_OBJ_NAME}
+    PRIVATE OpenCL-Headers
   )
 
   find_package(Threads REQUIRED)
 
   target_link_libraries(${LIB_NAME}
     PRIVATE
-      ${OpenCL_LIBRARIES}
+      OpenCL-ICD
       ${CMAKE_DL_LIBS}
       ${CMAKE_THREAD_LIBS_INIT}
     PUBLIC